Как отловить завершение программы(закрытие окна)?

[Wylde]

В VB 6.0 через shell запускается программа копирования файла. По завершении копирования окно программы закрывается. Требуется отловить момент закрытия окна. Как это сделать и как заставить VB не выполнять никаких действий пока не завершиться копирование?

 

[XOXOJI]

Как запустить программу и дождаться завершения ее работы

Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type

Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type

Private Declare Function CloseHandle Lib "kernel32" _
(ByVal hObject As Long) As Long
Private Declare Function CreateProcessA Lib "kernel32" _
(ByVal lpApplicationName As Long, ByVal lpCommandLine As String, _
ByVal lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) _
As Long

Private Declare Function WaitForSingleObject Lib "kernel32" _
(ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long

Private Const INFINITE = -1&
Private Const NORMAL_PRIORITY_CLASS = &H20&

Dim FileName As String

Private Sub RunFile(FileName)
Dim Process As PROCESS_INFORMATION
Dim Prog As STARTUPINFO
Prog.cb = Len(Prog)
CreateProcessA 0&, FileName, 0&, 0&, 1&, _
NORMAL_PRIORITY_CLASS, 0&, 0&, Prog, Process
WaitForSingleObject Process.hProcess, INFINITE
CloseHandle Process.hProcess
End Sub

Private Sub Command1_Click()
MsgBox "Программа запущена"
RunFile "c:\windows\notepad.exe"
MsgBox "Программа закрыта"
End Sub

 

[Wylde]

Примного благодарен. Это действительно то что было нужно!