Вопрос по работе с Cmd.exe

Тема в разделе "Visual Basic", создана пользователем aiswork, 22 май 2009.

Статус темы:
Закрыта.
  1. aiswork

    aiswork Гость

    Всем привет!
    Имею проблему и прошу помочь.
    Суть вопроса в следующем:
    как из VB кода записать команду (например HELP) в cmd.exe и затем выполнить ее, после чего завершить работу cmd.exe?
    Заранее спасибо.
     
  2. Tanya

    Tanya Гость

    Код (Text):
    Private Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Long
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
    End Type

    Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessID As Long
    dwThreadID As Long
    End Type

    Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
    hHandle As Long, ByVal dwMilliseconds As Long) As Long

    Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
    lpApplicationName As String, ByVal lpCommandLine As String, ByVal _
    lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
    ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
    ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As String, _
    lpStartupInfo As STARTUPINFO, lpProcessInformation As _
    PROCESS_INFORMATION) As Long

    Private Declare Function CloseHandle Lib "kernel32" _
    (ByVal hObject As Long) As Long

    Private Declare Function GetExitCodeProcess Lib "kernel32" _
    (ByVal hProcess As Long, lpExitCode As Long) As Long


    Private Const NORMAL_PRIORITY_CLASS = &H20&
    Private Const INFINITE = -1&

    Public Function ExecCmd(cmdline$)
    Dim proc As PROCESS_INFORMATION
    Dim start As STARTUPINFO
    Dim ret&

    ' Initialize the STARTUPINFO structure:
    start.cb = Len(start)

    ' Start the shelled application:
    ret& = CreateProcessA(vbNullString, cmdline$, 0&, 0&, 1&, _
    NORMAL_PRIORITY_CLASS, 0&, vbNullString, start, proc)

    ' Wait for the shelled application to finish:
    ret& = WaitForSingleObject(proc.hProcess, INFINITE)
    Call GetExitCodeProcess(proc.hProcess, ret&)
    Call CloseHandle(proc.hThread)
    Call CloseHandle(proc.hProcess)
    ExecCmd = ret&
    End Function


    Private Sub Command1_Click()
    Dim retval As Long

    ' ключ /k - выводит хелп на экран и ждет ответа
    ' ключ /с - выводит хелп и сразу же завершает работу cmd
    ' справка по этим ключам для команды cmd есть в Windows

    'Вариант 1. Запускаем cmd.exe и продолжаем работать дальше, cmd сам себе, прога сама себе   
    'Shell "cmd /k help", vbNormalFocus

    ' Вариант 2. Запускаем cmd.exe и ждем окончания работы cmd
    retval = ExecCmd("cmd /k help")
    MsgBox "Process Finished, Exit Code " & retval

    End Sub
     
Загрузка...
Похожие Темы - Вопрос по работе
  1. Eugen
    Ответов:
    9
    Просмотров:
    2.268
  2. tumanovalex
    Ответов:
    1
    Просмотров:
    1.595
  3. vladis222
    Ответов:
    1
    Просмотров:
    1.304
  4. DjTouch
    Ответов:
    1
    Просмотров:
    3.191
  5. ApplePen
    Ответов:
    0
    Просмотров:
    60
Статус темы:
Закрыта.

Поделиться этой страницей